Outre son importance pour la création de programmes tournant en mode DOS, Turbo Pascal permet également d'adjoindre à ces applications une interface graphique.
Nous serons donc en mesure de créer des fichiers console avec des menus, des décors, et le tout sur mesure !
En fait, Turbo Pascal initialise les modes graphiques en utilisant des pilotes qui peuvent se trouver dans le repertoire /BGI. Entre autres, nous avons EGAVGA.BGI et VESA16.BGI qui permettent d'initialiser des modes spécifiques.
De nombreuses fonctions et procédures sont fournies par Turbo Pascal, à l'instar de InitGraph, DetectGraph, GraphResult, etc... qui sont toutes clairement définies, exemple à l'appui, dans l'aide de TP.
La liste exhaustive des fonctions et procédures de l'unité Graph (celle qui nous permet de gérer le graphisme) peut être obtenue en consultant tout simplement l'aide sur Graph.

Initialiser le mode graphique et dessiner un repère gradué où est dessiné un losange de centre de gravité l'origine du repère.

Solution : Voir le fichier Repere1.pas

program repere;
uses graph;
 
var
  driver, mode: integer;
  i, j: integer;
begin
  driver := Detect;
  InitGraph(driver, mode, 'c:\tp\bgi');
  if (GraphResult <> grOk) then
  begin
    writeln('Erreur au cours de l''initialisation du mode graphique');
    halt(1);
  end;
 
  Line(0, 220, 630, 220);
  Line(315, 0, 315, 460);
 
  i := 0;
  j := 0;
 
  while (i <= 460) do
  begin
    Line(313, i, 317, i);
    i := i + 20;
  end;
  while (j <= 630) do
  begin
    Line(j, 218, j, 222);
    j := j + 30
  end;
 
  Line(315, 100, 120, 220);
  Line(315, 100, 510, 220);
  Line(315, 340, 120, 220);
  Line(315, 340, 510, 220);
 
  readln;
  CloseGraph;
 
end.

Commentaire :

• Nous utilisons la fonction GraphResult pour connaître si oui ou non l'initialisation du mode graphique a été réussie (un peu comme la fonction IOResult pour les entrées/sorties). Comme précisé plus haut, il est possible d'avoir la liste exhaustive des fonctions et procédures de l'unité Graph, dont Line fait partie, en demandant l'aide sur le mot Graph ! La procédure Halt interrompt l'exécution du programme et redonne la main au système d'exploitation.

Réalisation d'un menu interactif

Le but de l'exercice est de modifier l'interface graphique du programme en fonction du clavier.

• Dessiner trois boutons (rectangles) de couleur (de fond) rouge. Ces trois boîtes s'appelent respectivement A, B et C.
• Capter les touches du clavier, et si la lettre correspondant à une des boîtes est tapée, alors, cette boîte de vient de couleur bleue pendant 2 secondes et un son différent pour chaque touche est émis. Ecrire en haut de chaque bouton son nom.
• L'utilisateur a la possibilité de quitter le programme en appuyant sur la touche Esc.

Préréquis : Consultez l'aide sur les fonctions Bar, Bar3D, OutText et OutTextXY.

Solution : Voir le fichier Graphrea.pas

program graphinterac;
uses crt, graph;
 
var
  driver, mode: integer;
  letter: char;
 
begin
  driver := Detect;
  InitGraph(driver, mode, 'c:\tp\bgi');
  if (GraphResult <> grOk) then
  begin
    writeln('Erreur au cours de l''initialisation du mode graphique');
    halt(1);
  end;
 
  SetFillStyle(1, red);
  Bar(50, 80, 200, 100);
  Bar(250, 80, 400, 100);
  Bar(450, 80, 600, 100);
  OutTextXY(75, 70, 'Le bouton A');
  OutTextXY(275, 70, 'Le bouton B');
  OutTextXY(475, 70, 'Le bouton C');
 
  repeat
    letter := readkey;
    case letter of
      'a', 'A':
        begin
          sound(250);
          delay(50);
          nosound;
          SetFillStyle(1, blue);
          Bar(50, 80, 200, 100);
          delay(2000);
          SetFillStyle(1, red);
          Bar(50, 80, 200, 100);
        end;
      'b', 'B':
        begin
          sound(350);
          delay(50);
          nosound;
          SetFillStyle(1, blue);
          Bar(250, 80, 400, 100);
          delay(2000);
          SetFillStyle(1, red);
          Bar(250, 80, 400, 100);
        end;
      'c', 'C':
        begin
          sound(450);
          delay(50);
          nosound;
          SetFillStyle(1, blue);
          Bar(450, 80, 600, 100);
          delay(2000);
          SetFillStyle(1, red);
          Bar(450, 80, 600, 100);
        end;
    else
      begin
        sound(150);
        delay(50);
        nosound;
      end;
    end;
  until letter = #27;
 
  CloseGraph;
end.